| Home Page | Recent Changes | Preferences

# Dma/MutMultiJumpConfig

- See also dma/MutMultiJump

## Output

- http://www.coe.uncc.edu/~danderse/www/MultiJump-DMA3.zip

## Source

    //=============================================================================
    // MutMultiJumpConfig - Configuation page for MultiJump
    //=============================================================================
    class MutMultiJumpConfig extends GUIPage;

    function InitComponent(GUIController MyController, GUIComponent MyOwner)
    {
       // I could probably bypass this by using the IniOption properties of these controls.

       Super.InitComponent(MyController, MyOwner);

       moNumericEdit(Controls[2]).SetValue(class'MutMultiJump'.default.MaxMultiJumpCount);
       moNumericEdit(Controls[3]).SetValue(class'MutMultiJump'.default.MultiJumpBoost);

       return;
    }

    function bool SaveAndClose(GUIComponent Sender)
    {
       class'MutMultiJump'.default.MaxMultiJumpCount = moNumericEdit(Controls[2]).GetValue();
       class'MutMultiJump'.default.MultiJumpBoost = moNumericEdit(Controls[3]).GetValue();
       class'MutMultiJump'.static.StaticSaveConfig();

       Controller.CloseMenu(false);

       return true;
    }

    defaultproperties
    {
       Begin Object Class=GUIButton name=DialogBackground
          WinWidth=0.70
          WinHeight=0.85
          WinTop=0.0
          WinLeft=0.15
          bAcceptsInput=false
          bNeverFocus=true
          StyleName="ComboListBox"
          bBoundToParent=true
          bScaleToParent=true
       End Object
       Controls(0)=GUIButton'DialogBackground'

       Begin Object class=GUILabel Name=MutMultiJumpHeader
          Caption="Multiple Jumping!"
          TextALign=TXTA_Center
          TextColor=(R=230,G=200,B=0,A=255)
          TextFont="UT2HeaderFont"
          WinWidth=1
          WinLeft=0
          WinTop=0.35
          WinHeight=32
       End Object
       Controls(1)=GUILabel'MutMultiJumpHeader'

       Begin Object class=moNumericEdit Name=MutMultiJumpCount
          WinWidth=0.450000
          WinHeight=0.060000
          WinLeft=0.325
          WinTop=0.43
          Caption="Number of Jumps"
          Hint="How many multijumps should players be allowed?"
          CaptionWidth=0.5
          ComponentWidth=0.55
          MinValue=0
          MaxValue=1000000
          // IniOption="ini:MultiJump.MutMultiJump.MaxMultiJumpCount"
       End Object
       Controls(2)=moNumericEdit'MutMultiJumpCount'

       Begin Object class=moNumericEdit Name=MutMultiJumpBoost
          WinWidth=0.450000
          WinHeight=0.060000
          WinLeft=0.325
          WinTop=0.50
          Caption="Boost Amount"
          Hint="How high should each multijump boost the player?"
          CaptionWidth=0.5
          ComponentWidth=0.55
          MinValue=0
          MaxValue=1000000
          // IniOption="ini:MultiJump.MutMultiJump.MultiJumpBoost"
       End Object
       Controls(3)=moNumericEdit'MutMultiJumpBoost'

       Begin Object Class=GUIButton Name=MutMultiJumpOkButton
          WinLeft=0.40
          WinTop=0.60
          WinWidth=0.20
          WinHeight=0.06
          OnClick=SaveAndClose
          Caption="OK"
       End Object
       Controls(4)=GUIButton'MutMultiJumpOkButton'

       WinTop=0.300000
       WinLeft=0.200000
       WinWidth=0.600000
       WinHeight=0.470000
    }

- Category Custom Class

The Unreal Engine Documentation Site

Wiki Community

Topic Categories

Image Uploads

Random Page

Recent Changes

Offline Wiki

Unreal Engine

Console Commands

Terminology

Mapping Topics

Mapping Lessons

UnrealEd Interface

Questions&Answers

Scripting Topics

Scripting Lessons

Making Mods

Class Tree

Questions&Answers

Modeling Topics

Questions&Answers

Log In