class NuclearLauncherLvlA expands NaliWeapons;

//1st person with missile
#exec MESH IMPORT MESH=NukeLauncher ANIVFILE=MODELS\NukeLauncherOne_a.3d DATAFILE=MODELS\NukeLauncherOne_d.3d X=0 Y=0 Z=0
#exec MESH LODPARAMS MESH=NukeLauncher STRENGTH=0
#exec MESH ORIGIN MESH=NukeLauncher X=0 Y=0 Z=0 YAW=128

//1st person right handed with missile
#exec MESH IMPORT MESH=NukeLauncherR ANIVFILE=MODELS\NukeLauncherOne_a.3d DATAFILE=MODELS\NukeLauncherOne_d.3d X=0 Y=0 Z=0 UNMIRROR=1
#exec MESH LODPARAMS MESH=NukeLauncherR STRENGTH=0
#exec MESH ORIGIN MESH=NukeLauncherR X=0 Y=0 Z=0

//1st person with no missile
#exec MESH IMPORT MESH=NukeLauncherW ANIVFILE=MODELS\NukeLauncherM_a.3d DATAFILE=MODELS\NukeLauncherM_d.3d X=0 Y=0 Z=0
#exec MESH LODPARAMS MESH=NukeLauncherW STRENGTH=0
#exec MESH ORIGIN MESH=NukeLauncherW X=0 Y=0 Z=0 YAW=128

//1st person right handed with no missile
#exec MESH IMPORT MESH=NukeLauncherRW ANIVFILE=MODELS\NukeLauncherM_a.3d DATAFILE=MODELS\NukeLauncherM_d.3d X=0 Y=0 Z=0 UNMIRROR=1
#exec MESH LODPARAMS MESH=NukeLauncherRW STRENGTH=0
#exec MESH ORIGIN MESH=NukeLauncherRW X=0 Y=0 Z=0

//Pickup with missile
#exec MESH IMPORT MESH=NukeLauncherPick ANIVFILE=MODELS\NukeLauncherOne_a.3d DATAFILE=MODELS\NukeLauncherOne_d.3d X=0 Y=0 Z=0
//#exec MESH LODPARAMS MESH=NukeLauncherPick STRENGTH=0
#exec MESH ORIGIN MESH=NukeLauncherPick X=0 Y=0 Z=0 YAW=128

//Pickup with no missile
#exec MESH IMPORT MESH=NukeLauncherPickW ANIVFILE=MODELS\NukeLauncherM_a.3d DATAFILE=MODELS\NukeLauncherM_d.3d X=0 Y=0 Z=0
//#exec MESH LODPARAMS MESH=NukeLauncherPickW STRENGTH=0
#exec MESH ORIGIN MESH=NukeLauncherPickW X=0 Y=0 Z=0 YAW=128

//3rd person with missile
#exec MESH IMPORT MESH=NukeLauncherM ANIVFILE=MODELS\NukeLauncherOne_a.3d DATAFILE=MODELS\NukeLauncherOne_d.3d X=0 Y=0 Z=0
#exec MESH LODPARAMS MESH=NukeLauncherM STRENGTH=0
#exec MESH ORIGIN MESH=NukeLauncherM X=608 Y=0 Z=-78 YAW=128

//3rd person with no missile
#exec MESH IMPORT MESH=NukeLauncherMW ANIVFILE=MODELS\NukeLauncherM_a.3d DATAFILE=MODELS\NukeLauncherM_d.3d X=0 Y=0 Z=0
#exec MESH LODPARAMS MESH=NukeLauncherMW STRENGTH=0
#exec MESH ORIGIN MESH=NukeLauncherMW X=608 Y=0 Z=-78 YAW=128

//-----------------------------------------------------------------------------------

//Animations
#exec MESH SEQUENCE MESH=NukeLauncher SEQ=All STARTFRAME=0 NUMFRAMES=22
#exec MESH SEQUENCE MESH=NukeLauncher SEQ=Still STARTFRAME=0 NUMFRAMES=1
#exec MESH SEQUENCE MESH=NukeLauncher SEQ=Fire STARTFRAME=0 NUMFRAMES=13 RATE=13.0
#exec MESH SEQUENCE MESH=NukeLauncher SEQ=Down STARTFRAME=12 NUMFRAMES=5 RATE=14.0
#exec MESH SEQUENCE MESH=NukeLauncher SEQ=Select STARTFRAME=16 NUMFRAMES=5 RATE=7.0 GROUP=Select
#exec MESH SEQUENCE MESH=NukeLauncher SEQ=Lock STARTFRAME=20 NUMFRAMES=2 RATE=1.0

#exec MESH SEQUENCE MESH=NukeLauncherR SEQ=All STARTFRAME=0 NUMFRAMES=22
#exec MESH SEQUENCE MESH=NukeLauncherR SEQ=Still STARTFRAME=0 NUMFRAMES=1
#exec MESH SEQUENCE MESH=NukeLauncherR SEQ=Fire STARTFRAME=0 NUMFRAMES=13 RATE=13.0
#exec MESH SEQUENCE MESH=NukeLauncherR SEQ=Down STARTFRAME=12 NUMFRAMES=5 RATE=14.0
#exec MESH SEQUENCE MESH=NukeLauncherR SEQ=Select STARTFRAME=16 NUMFRAMES=5 RATE=7.0 GROUP=Select
#exec MESH SEQUENCE MESH=NukeLauncherR SEQ=Lock STARTFRAME=20 NUMFRAMES=2 RATE=1.0

#exec MESH SEQUENCE MESH=NukeLauncherW SEQ=All STARTFRAME=0 NUMFRAMES=22
#exec MESH SEQUENCE MESH=NukeLauncherW SEQ=Still STARTFRAME=0 NUMFRAMES=1
#exec MESH SEQUENCE MESH=NukeLauncherW SEQ=Fire STARTFRAME=0 NUMFRAMES=13 RATE=13.0
#exec MESH SEQUENCE MESH=NukeLauncherW SEQ=Down STARTFRAME=12 NUMFRAMES=5 RATE=14.0
#exec MESH SEQUENCE MESH=NukeLauncherW SEQ=Select STARTFRAME=16 NUMFRAMES=5 RATE=7.0 GROUP=Select
#exec MESH SEQUENCE MESH=NukeLauncherW SEQ=Lock STARTFRAME=20 NUMFRAMES=2 RATE=1.0

#exec MESH SEQUENCE MESH=NukeLauncherRW SEQ=All STARTFRAME=0 NUMFRAMES=22
#exec MESH SEQUENCE MESH=NukeLauncherRW SEQ=Still STARTFRAME=0 NUMFRAMES=1
#exec MESH SEQUENCE MESH=NukeLauncherRW SEQ=Fire STARTFRAME=0 NUMFRAMES=13 RATE=13.0
#exec MESH SEQUENCE MESH=NukeLauncherRW SEQ=Down STARTFRAME=12 NUMFRAMES=5 RATE=14.0
#exec MESH SEQUENCE MESH=NukeLauncherRW SEQ=Select STARTFRAME=16 NUMFRAMES=5 RATE=7.0 GROUP=Select
#exec MESH SEQUENCE MESH=NukeLauncherRW SEQ=Lock STARTFRAME=20 NUMFRAMES=2 RATE=1.0

#exec MESH SEQUENCE MESH=NukeLauncherPick SEQ=Still STARTFRAME=0 NUMFRAMES=1

#exec MESH SEQUENCE MESH=NukeLauncherPickW SEQ=Still STARTFRAME=0 NUMFRAMES=1

#exec MESH SEQUENCE MESH=NukeLauncherM SEQ=Still STARTFRAME=0 NUMFRAMES=1
#exec MESH SEQUENCE MESH=NukeLauncherM SEQ=Fire STARTFRAME=0 NUMFRAMES=13 RATE=13.0

#exec MESH SEQUENCE MESH=NukeLauncherMW SEQ=Still STARTFRAME=0 NUMFRAMES=1
#exec MESH SEQUENCE MESH=NukeLauncherMW SEQ=Fire STARTFRAME=0 NUMFRAMES=13 RATE=13.0

//-----------------------------------------------------------------------------------

//Scale
#exec MESHMAP NEW MESHMAP=NukeLauncher MESH=NukeLauncher
#exec MESHMAP SCALE MESHMAP=NukeLauncher X=0.05 Y=0.05 Z=0.1

#exec MESHMAP NEW MESHMAP=NukeLauncherR MESH=NukeLauncherR
#exec MESHMAP SCALE MESHMAP=NukeLauncherR X=0.05 Y=0.05 Z=0.1

#exec MESHMAP NEW MESHMAP=NukeLauncherRW MESH=NukeLauncherRW
#exec MESHMAP SCALE MESHMAP=NukeLauncherRW X=0.05 Y=0.05 Z=0.1

#exec MESHMAP NEW MESHMAP=NukeLauncherW MESH=NukeLauncherW
#exec MESHMAP SCALE MESHMAP=NukeLauncherW X=0.05 Y=0.05 Z=0.1

#exec MESHMAP NEW MESHMAP=NukeLauncherPick MESH=NukeLauncherPick
#exec MESHMAP SCALE MESHMAP=NukeLauncherPick X=0.05 Y=0.05 Z=0.1

#exec MESHMAP NEW MESHMAP=NukeLauncherPickW MESH=NukeLauncherPickW
#exec MESHMAP SCALE MESHMAP=NukeLauncherPickW X=0.05 Y=0.05 Z=0.1

#exec MESHMAP NEW MESHMAP=NukeLauncherM MESH=NukeLauncherM
#exec MESHMAP SCALE MESHMAP=NukeLauncherM X=0.05 Y=0.05 Z=0.1

#exec MESHMAP NEW MESHMAP=NukeLauncherMW MESH=NukeLauncherMW
#exec MESHMAP SCALE MESHMAP=NukeLauncherMW X=0.05 Y=0.05 Z=0.1

//-----------------------------------------------------------------------------------

//Skins
#exec TEXTURE IMPORT NAME=XNukeSk FILE=SKINS\XNukeSk.bmp GROUP=Skins FLAGS=2 LODSET=2
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncher NUM=1 TEXTURE=XNukeSk
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherR NUM=1 TEXTURE=XNukeSk
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherPick NUM=1 TEXTURE=XNukeSk
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherM NUM=1 TEXTURE=XNukeSk

#exec TEXTURE IMPORT NAME=XLauncherSk01 FILE=SKINS\XLauncherSk01.bmp GROUP=Skins FLAGS=2 LODSET=2
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherW NUM=1 TEXTURE=XLauncherSk01
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherRW NUM=1 TEXTURE=XLauncherSk01
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherPickW NUM=1 TEXTURE=XLauncherSk01
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherMW NUM=1 TEXTURE=XLauncherSk01
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncher NUM=2 TEXTURE=XLauncherSk01
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherR NUM=2 TEXTURE=XLauncherSk01
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherPick NUM=2 TEXTURE=XLauncherSk01
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherM NUM=2 TEXTURE=XLauncherSk01

#exec TEXTURE IMPORT NAME=XLauncherSk02 FILE=SKINS\XLauncherSk02.bmp GROUP=Skins FLAGS=2 LODSET=2
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherW NUM=2 TEXTURE=XLauncherSk02
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherRW NUM=2 TEXTURE=XLauncherSk02
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherPickW NUM=2 TEXTURE=XLauncherSk02
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherMW NUM=2 TEXTURE=XLauncherSk02
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncher NUM=3 TEXTURE=XLauncherSk02
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherR NUM=3 TEXTURE=XLauncherSk02
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherPick NUM=3 TEXTURE=XLauncherSk02
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherM NUM=3 TEXTURE=XLauncherSk02

#exec TEXTURE IMPORT NAME=XLauncherSk03 FILE=SKINS\XLauncherSk03.bmp GROUP=Skins FLAGS=2 LODSET=2
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherW NUM=3 TEXTURE=XLauncherSk03
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherRW NUM=3 TEXTURE=XLauncherSk03
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherPickW NUM=3 TEXTURE=XLauncherSk03
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherMW NUM=3 TEXTURE=XLauncherSk03
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncher NUM=4 TEXTURE=XLauncherSk03
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherR NUM=4 TEXTURE=XLauncherSk03
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherPick NUM=4 TEXTURE=XLauncherSk03
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherM NUM=4 TEXTURE=XLauncherSk03

#exec TEXTURE IMPORT NAME=MetalShine FILE=SKINS\MetalShine.bmp GROUP=Skins FLAGS=2 LODSET=2
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherW NUM=4 TEXTURE=MetalShine
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherRW NUM=4 TEXTURE=MetalShine
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherPickW NUM=4 TEXTURE=MetalShine
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherMW NUM=4 TEXTURE=MetalShine
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncher NUM=5 TEXTURE=MetalShine
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherR NUM=5 TEXTURE=MetalShine
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherPick NUM=5 TEXTURE=MetalShine
#exec MESHMAP SETTEXTURE MESHMAP=NukeLauncherM NUM=5 TEXTURE=MetalShine

//--------------------------------------------------------------

//Icons
#exec TEXTURE IMPORT NAME=NukeIcon1 FILE=ICONS\NukeIcon1.bmp GROUP=Icons MIPS=OFF

#exec OBJ LOAD FILE=Textures\NaliIcons.utx PACKAGE=NaliWeaponsII.Icons

//-----------------------------------------------------------------------------------

//Sounds
#exec AUDIO IMPORT NAME="AltNukeLock" FILE=SOUNDS\AltNukeLock.wav GROUP="NukeLauncher"
#exec AUDIO IMPORT NAME="AltNukeTime" FILE=SOUNDS\AltNukeTime.wav GROUP="NukeLauncher"
#exec AUDIO IMPORT NAME="NukeDeactHome" FILE=SOUNDS\NukeDeactHome.wav GROUP="NukeLauncher"
#exec AUDIO IMPORT NAME="NukeHomeActive" FILE=SOUNDS\NukeHomeActive.wav GROUP="NukeLauncher"
#exec AUDIO IMPORT NAME="NukeFire" FILE=SOUNDS\NukeFire.wav GROUP="NukeLauncher"
#exec AUDIO IMPORT NAME="NukePick" FILE=SOUNDS\NukePick.wav GROUP="NukeLauncher"
#exec AUDIO IMPORT NAME="NukeSelect" FILE=SOUNDS\NukeSelect.wav GROUP="NukeLauncher"


var() class<NukeMissileA> NukeProjectile;
var byte HomeStg;

var vector TrgtLoc;
var float HomingDelay;
var Font NeoF;
var bool bHomingMode;

var NukeHomeCrossA NkHCa;
var NukeHomeCrossB NkHCb;

replication
{
	reliable if(ROLE == Role_Authority && bNetOwner)
		HomeStg;
	reliable if(Role==ROLE_Authority)
		TrgtLoc, HomingDelay, bHomingMode;
}


function setHand(float Hand)
{
	Super.SetHand(Hand);
	if ( Hand == 1 )
	{
		Mesh = mesh'NukeLauncher';
		PlayerViewMesh = mesh'NukeLauncher';
	}
	else
	{
		Mesh = mesh'NukeLauncherR';
		PlayerViewMesh = mesh'NukeLauncherR';
	}
}

simulated function Destroyed()
{
	if (NkHCa != None)
		NkHCa.Destroy();
	if (NkHCb != None)
		NkHCb.Destroy();

	Super.Destroyed();
}


simulated function PostRender( canvas Canvas )
{
	local PlayerPawn P;
	local float Scale, ZoomS;
	local float XL, YL;

	P = PlayerPawn(Owner);

	Super.PostRender(Canvas);

	
	if (HomeStg != 0)
	{
		Scale = Canvas.ClipX/640;
		Canvas.Style = ERenderStyle.STY_Normal;

		if (NkHCb != None)
			Canvas.DrawActor( NkHCb, False, True);
		if (NkHCa != None)
			Canvas.DrawActor( NkHCa, False, True);

		if (HomeStg == 1)
		{
		Canvas.DrawColor.R = 255;
		Canvas.DrawColor.G = 0;
		Canvas.DrawColor.B = 0;
		Canvas.Font = NeoF;
		Canvas.StrLen("HOMING TARGET LOCKED", XL, YL);
		Canvas.SetPos(0.5*Canvas.ClipX - XL/2, 0.5*Canvas.ClipY - 64*Scale);
		Canvas.DrawText("HOMING TARGET LOCKED", True);

		Canvas.DrawColor.R = 0;
		Canvas.DrawColor.G = 255;
		Canvas.DrawColor.B = 0;
		Canvas.Font = NeoF;
		Canvas.StrLen(int(HomingDelay)$":00", XL, YL);
		Canvas.SetPos(0.5*Canvas.ClipX - XL/2, 0.5*Canvas.ClipY + 64*Scale);
		Canvas.DrawText(int(HomingDelay)$":00");
		}
		else
		{
		Canvas.DrawColor.R = 255;
		Canvas.DrawColor.G = 255;
		Canvas.DrawColor.B = 0;
		Canvas.Font = NeoF;
		Canvas.StrLen("HOMING TARGET LOCKED", XL, YL);
		Canvas.SetPos(0.5*Canvas.ClipX - XL/2, 0.5*Canvas.ClipY - 64*Scale);
		Canvas.DrawText("HOMING TARGET LOCKED", True);

		Canvas.DrawColor.R = 128;
		Canvas.DrawColor.G = 128;
		Canvas.DrawColor.B = 0;
		Canvas.Font = NeoF;
		Canvas.StrLen(int(HomingDelay)$":00", XL, YL);
		Canvas.SetPos(0.5*Canvas.ClipX - XL/2, 0.5*Canvas.ClipY + 64*Scale);
		Canvas.DrawText(int(HomingDelay)$":00");
		}
	}
	
}


function Fire( float Value )
{
local NukeMissileA pj;

	if (HomeStg != 1)
	{

    if ( (AmmoType == None) && (AmmoName != None) )
    {
        // ammocheck
        GiveAmmo(Pawn(Owner));
    }

	if (AmmoType.UseAmmo(1))
	{
        	GotoState('NormalFire');
        	bPointing=True;
        	bCanClientFire = true;
        	ClientFire(Value);

		pj = NukeMissileA(ProjectileFire(NukeProjectile, ProjectileSpeed, bWarnTarget));

		pj.TrgtLoc = TrgtLoc;
		pj.HomingDelay = HomingDelay;
		pj.bHomingMode = bHomingMode;

		bHomingMode = False;
	}

	}
	else
	{
		GotoState('NormalFire');
        	bPointing=True;
        	bCanClientFire = true;
        	ClientFire(Value);
	}
}


simulated function PlayFiring()
{
	if (HomeStg != 1)
	{
	PlayAnim('Fire', 1.0, 0.0);
	if (Mesh == mesh'NukeLauncher')
		Mesh = mesh'NukeLauncherW';
	if (Mesh == mesh'NukeLauncherR')
		Mesh = mesh'NukeLauncherRW';
	if (PlayerViewMesh == mesh'NukeLauncher')
		PlayerViewMesh = mesh'NukeLauncherW';
	if (PlayerViewMesh == mesh'NukeLauncherR')
		PlayerViewMesh = mesh'NukeLauncherRW';
	ThirdPersonMesh = mesh'NukeLauncherMW';

	PlayOwnedSound(FireSound, SLOT_None, Pawn(Owner).SoundDampening*8.0);

	HomeStg = 0;

	if (NkHCa != None)
	{
		NkHCa.Destroy();
		NkHCa = None;
	}
	if (NkHCb != None)
	{
		NkHCb.Destroy();
		NkHCb = None;
	}
		
	}
	else
	{
		HomeStg++;
		PlayAnim('Lock', 2.5, 0.0);
		PlayOwnedSound(Sound'NukeHomeActive', SLOT_None, Pawn(Owner).SoundDampening*3.0);
	}
}


function AltFire( float Value )
{
        GotoState('AltFiring');
        bPointing=True;
        bCanClientFire = true;
        ClientAltFire(Value);
}

simulated function PlayAltFiring()
{
local vector StartTrace, EndTrace, HitLocation, HitNormal, X, Y, Z;
local Actor LTarget;


	PlayAnim('Lock', 2.5, 0.0);

	if (HomeStg == 0)
	{
		HomeStg++;
		bHomingMode = True;
		GetAxes(Pawn(Owner).ViewRotation,X,Y,Z);
		StartTrace = Owner.Location + Pawn(Owner).Eyeheight * Z;
		EndTrace = StartTrace + (64000 * X);

		LTarget = Trace( HitLocation, HitNormal, EndTrace, StartTrace, True);
		if (LTarget == None)
		{
			HitLocation = EndTrace;
			HitNormal = vector(PlayerPawn(Owner).ViewRotation);
		}

		TrgtLoc = HitLocation;

		NkHCa = Spawn(Class'NukeHomeCrossA',,, HitLocation + HitNormal, rotator(HitNormal));
		NkHCb = Spawn(Class'NukeHomeCrossB',,, HitLocation + HitNormal, rotator(HitNormal));

		PlayOwnedSound(Sound'AltNukeLock', SLOT_None, Pawn(Owner).SoundDampening*3.0);
	}
	else if (HomeStg == 1)
	{
		if (HomingDelay == 2)
			HomingDelay = 3;
		else if (HomingDelay == 3)
			HomingDelay = 5;
		else if (HomingDelay == 5)
			HomingDelay = 10;
		else
			HomingDelay = 2;

		PlayOwnedSound(Sound'AltNukeTime', SLOT_None, Pawn(Owner).SoundDampening*3.0);
	}
	else
	{
		if (NkHCa != None)
		{
			NkHCa.Destroy();
			NkHCa = None;
		}
		if (NkHCb != None)
		{
			NkHCb.Destroy();
			NkHCb = None;
		}
		bHomingMode = False;
		HomeStg = 0;
		PlayOwnedSound(Sound'NukeDeactHome', SLOT_None, Pawn(Owner).SoundDampening*3.0);
	}
}


simulated function PlaySelect()
{
    bForceFire = false;
    bForceAltFire = false;
    bCanClientFire = false;
	ThirdPersonMesh = mesh'NukeLauncherM';
	if ( PlayerPawn(Owner).Handedness == 1 )
	{
		Mesh = mesh'NukeLauncher';
		PlayerViewMesh = mesh'NukeLauncher';
	}
	else
	{
		Mesh = mesh'NukeLauncherR';
		PlayerViewMesh = mesh'NukeLauncherR';
	}
    if ( !IsAnimating() || (AnimSequence != 'Select') )
        PlayAnim('Select',1.0,0.0);
    Owner.PlaySound(SelectSound, SLOT_Misc, Pawn(Owner).SoundDampening);    
}



defaultproperties
{
	DrawType=DT_Mesh
	Mesh=NukeLauncherPick
	CollisionHeight=12.000000
	CollisionRadius=15.000000
	AutoSwitchPriority=10
	Icon=NukeIcon1
	InventoryGroup=10
	ItemArticle="a"
	ItemName="Nuclear Launcher Lvl 1 - Class SL"
	MaxDesireability=2.000000
	PickupMessage="You got the Nuclear Launcher Lvl 1 - Class SL"
	PickupSound=NukePick
	PickupViewMesh=NukeLauncherPick
	PickupViewScale=1.000000
	PlayerViewMesh=NukeLauncher
	PlayerViewOffset=(X=30.000000,Y=-20.000000,Z=-12.000000)
	PlayerViewScale=1.000000
	RespawnTime=60.000000
	StatusIcon=NukeIcon1
	ThirdPersonMesh=NukeLauncherM
	ThirdPersonScale=0.850000
	AltDamageType=None
	AltFireSound=None
	AltProjectileClass=None
	AmmoName=Class'NukeAmmoA'
	bRapidFire=False
	DeathMessage="%o was vaporized by %k's %w."
	FireOffset=(X=0.000000,Y=0.000000,Z=0.000000)
	FireSound=NukeFire
	FiringSpeed=1.000000
	MaxTargetRange=4096.000000
	MyDamageType=Nuked
	NameColor=(R=64,G=64,B=0)
	PickupAmmoCount=1
	ProjectileClass=None
	SelectSound=NukeSelect
	shakemag=400.000000
	shaketime=0.200000
	shakevert=15.000000
	AIRating=1.000000
	AltRefireRate=0.010000
	bAltWarnTarget=True
	bRecommendAltSplashDamage=False
	bRecommendSplashDamage=True
	bSplashDamage=True
	bWarnTarget=True
	RefireRate=1.200000
	Mass=150.000000
	bNoSmooth=False
	bOwnsCrossHair=True
	CustomCross=NukeLCross
	CrossHairSize=64
	Texture=MetalShine
	bMegaWeapon=True
	CrossHairScale=0.650000
	NukeProjectile=Class'NukeMissileA'
	HomingDelay=2.000000
	NeoF=Font'AlienNeoBig'
	bForceTranslucentCrossHair=True
}
